source: configure.ac @ 0f5b08e

release-1.10
Last change on this file since 0f5b08e was 06e04a9, checked in by David Benjamin <davidben@mit.edu>, 11 years ago
perlvariables - iteration N Later commits reworked a lot of this, but the use of GValue over void* was kept.
  • Property mode set to 100644
File size: 6.4 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2AC_INIT([BarnOwl],[1.10dev],[bug-barnowl@mit.edu])
3AM_INIT_AUTOMAKE([1.7.0 -Wall -Wno-portability foreign])
4m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
5
6AC_CONFIG_MACRO_DIR([m4])
7AC_CONFIG_HEADER([config.h])
8
9AC_PROG_CC
10AC_PROG_CC_C99
11
12AC_ARG_WITH([stack-protector],
13  [AS_HELP_STRING([--with-stack-protector],
14    [Enable gcc -fstack-protector])],
15  [],
16  [with_stack_protector=check])
17
18AS_IF([test "x$with_stack_protector" != xno],
19  [AX_CHECK_COMPILE_FLAG([-fstack-protector],
20    [AM_CFLAGS="$AM_CFLAGS -fstack-protector"],
21    [if test "x$with_stack_protector" != xcheck; then
22       AC_MSG_FAILURE([--with-stack-protector selected, but gcc does support it.])
23     fi
24    ])])
25
26AC_CHECK_LIB(ncursesw, initscr,, AC_MSG_ERROR(No libncursesw found.))
27AC_CHECK_LIB(panelw, update_panels,, AC_MSG_ERROR(No libpanelw found.))
28AC_SEARCH_LIBS([gethostbyname], [nsl])
29AC_SEARCH_LIBS([socket], [socket])
30AC_SEARCH_LIBS([res_search], [resolv])
31
32AC_ARG_WITH([zephyr],
33  [AS_HELP_STRING([--with-zephyr],
34    [Enable Zephyr support])],
35  [],
36  [with_zephyr=check])
37
38AC_ARG_WITH([krb4],
39  AS_HELP_STRING([--with-krb4],
40                 [Build with kerberos IV]))
41
42AS_IF([test "x$with_zephyr" != xno],
43  [have_krb4=no
44
45   AS_IF([test "x$with_krb4" != "xno"],
46   [AC_MSG_CHECKING([for Kerberos IV])
47    AS_IF([krb5-config krb4 --libs >/dev/null 2>&1],
48      [AC_MSG_RESULT([yes])
49       have_krb4=yes
50       AC_DEFINE([HAVE_KERBEROS_IV], [1], [Define if you have kerberos IV])
51       AM_CFLAGS="${AM_CFLAGS} `krb5-config krb4 --cflags`"
52       LIBS="${LIBS} `krb5-config krb4 --libs`"
53      ],
54      [AC_MSG_RESULT([no])
55       AS_IF([test "x$with_krb4" = "xyes"],
56             [AC_MSG_ERROR([Kerberos IV requested but not found])])])])
57
58   AS_IF([test "x$have_krb4" != xyes],
59     [PKG_CHECK_MODULES([LIBCRYPTO], [libcrypto],
60        [AM_CFLAGS="${AM_CFLAGS} ${LIBCRYPTO_CFLAGS}"
61         LIBS="${LIBS} ${LIBCRYPTO_LIBS}"
62        ],
63        [PKG_CHECK_MODULES([OPENSSL], [openssl],
64           [AM_CFLAGS="${AM_CFLAGS} ${OPENSSL_CFLAGS}"
65            LIBS="${LIBS} ${OPENSSL_LIBS}"
66           ])])])
67
68   AC_CHECK_LIB([zephyr], [ZGetSender],
69   [LIBS="$LIBS -lzephyr"
70    AC_DEFINE([HAVE_LIBZEPHYR], [1],
71                [Define if you have libzephyr])
72    AC_CHECK_LIB([zephyr], [ZInitLocationInfo],
73      AC_DEFINE([HAVE_LIBZEPHYR_ZINITLOCATIONINFO], [1],
74                [Have ZInitLocationInfo]),)
75    AC_CHECK_LIB([com_err], [com_err])
76    AC_CHECK_HEADERS([com_err.h])
77   ],
78   [if test "x$with_zephyr" != xcheck; then
79      AC_MSG_FAILURE(
80        [--with-zephyr was given, but libzephyr does not seem to be available.])
81    fi
82   ])])
83
84AC_CHECK_FUNCS([use_default_colors])
85AC_CHECK_FUNCS([resizeterm], [], [AC_MSG_ERROR([No resizeterm found])])
86AC_CHECK_FUNCS([des_string_to_key DES_string_to_key], [HAVE_DES_STRING_TO_KEY=1])
87AC_CHECK_FUNCS([des_ecb_encrypt DES_ecb_encrypt], [HAVE_DES_ECB_ENCRYPT=1])
88AC_CHECK_FUNCS([des_key_sched DES_key_sched], [HAVE_DES_KEY_SCHED=1])
89
90dnl Checks for header files.
91AC_HEADER_STDC
92AC_HEADER_SYS_WAIT
93AC_CHECK_HEADERS(stdbool.h strings.h sys/ioctl.h sys/filio.h unistd.h)
94
95dnl Add CFLAGS for embeded perl
96PERL_CFLAGS=`perl -MExtUtils::Embed -e ccopts`
97AC_MSG_NOTICE([Adding perl CFLAGS ${PERL_CFLAGS}])
98AM_CFLAGS="${AM_CFLAGS} ${PERL_CFLAGS}"
99
100dnl Find the location of perl XSUBPP
101AC_MSG_CHECKING(for the perl xsubpp precompiler)
102XSUBPPDIR="`(perl -MExtUtils::MakeMaker -e 'print ExtUtils::MakeMaker->new({NAME => qw(owl)})->tool_xsubpp;') | grep \^XSUBPPDIR | sed -e 's/XSUBPPDIR = //g;'`"
103if test -n "${XSUBPPDIR}"; then
104   AC_MSG_RESULT(${XSUBPPDIR})
105else
106   AC_MSG_ERROR(not found)
107fi
108
109if test -f "${XSUBPPDIR}/typemap"; then
110   XSUBPPFLAGS="-typemap ${XSUBPPDIR}/typemap"
111else
112   XSUBPPFLAGS=""
113fi
114
115dnl Add LIBS for embedded perl
116FOO=`perl -MExtUtils::Embed -e ldopts`
117AC_MSG_NOTICE([Adding perl LIBS ${FOO}])
118LIBS=${LIBS}\ ${FOO}
119AC_CHECK_LIB([perl], [perl_alloc],, AC_MSG_ERROR([No libperl found]))
120
121AX_PROG_PERL_MODULES([AnyEvent],,
122                     [AC_MSG_ERROR([cannot find perl module AnyEvent.])])
123AX_PROG_PERL_MODULES([Class::Accessor::Fast],,
124                     [AC_MSG_ERROR([cannot find perl module Class::Accessor::Fast.])])
125AX_PROG_PERL_MODULES([Glib],,
126                     [AC_MSG_ERROR([cannot find perl module Glib.])])
127AX_PROG_PERL_MODULES([PAR],,
128                     [AC_MSG_WARN([PAR.pm not found. Loadable modules will be disabled.])])
129AX_PROG_PERL_MODULES([ExtUtils::Depends],,
130                     [AC_MSG_ERROR([cannot find perl module ExtUtils::Depends])])
131
132dnl Add CFLAGS and LIBS for glib-2.0
133PKG_CHECK_MODULES(GLIB,[glib-2.0 >= 2.16 gobject-2.0 gthread-2.0])
134
135AC_MSG_NOTICE([Adding glib-2.0 CFLAGS ${GLIB_CFLAGS}])
136AM_CFLAGS="${GLIB_CFLAGS} ${AM_CFLAGS}"
137AC_MSG_NOTICE([Adding glib-2.0 LIBS ${GLIB_LIBS}])
138LIBS="${GLIB_LIBS} ${LIBS}"
139
140if test "x${prefix}" = "xNONE"; then
141   prefix="${ac_default_prefix}"
142fi
143
144dnl Add CFLAGS for glib-perl
145GLIB_PERL_CFLAGS=`perl -MExtUtils::Depends -e 'my $e = ExtUtils::Depends->new("BarnOwl","Glib"); my %h = $e->get_makefile_vars; print $h{"INC"}'`
146AC_MSG_NOTICE([Adding glib-perl CFLAGS ${GLIB_PERL_CFLAGS}])
147AM_CFLAGS="${GLIB_PERL_CFLAGS} ${AM_CFLAGS}"
148
149dnl Checks for typedefs, structures, and compiler characteristics.
150
151AX_CFLAGS_WARN_ALL([AM_CFLAGS])
152AX_APPEND_COMPILE_FLAGS([-Wstrict-prototypes -Wwrite-strings],[AM_CFLAGS])
153
154dnl Shut gcc up about zero-length format strings; the warning's apparently for
155dnl efficiency reasons, which is bogus for custom functions.
156AX_APPEND_COMPILE_FLAGS([-Wno-format-zero-length],[AM_CFLAGS])
157
158AX_APPEND_COMPILE_FLAGS([-Wno-pointer-sign -Wno-empty-body -Wno-unused-value],[LIBFAIM_CFLAGS])
159
160AM_CONDITIONAL([ENABLE_ZCRYPT], [test "$HAVE_DES_STRING_TO_KEY" && dnl
161                                 test "$HAVE_DES_KEY_SCHED" && dnl
162                                 test "$HAVE_DES_ECB_ENCRYPT"])
163
164AM_CFLAGS="$AM_CFLAGS -D_XOPEN_SOURCE=600"
165dnl Define _BSD_SOURCE because zephyr needs caddr_t.
166AM_CFLAGS="$AM_CFLAGS -D_BSD_SOURCE"
167dnl Define __EXTENSIONS__ for strcasecmp on Solaris.
168AM_CFLAGS="$AM_CFLAGS -D__EXTENSIONS__"
169
170AC_SUBST([AM_CFLAGS])
171AC_SUBST([LIBFAIM_CFLAGS])
172
173AC_SUBST(XSUBPPDIR)
174AC_SUBST(XSUBPPFLAGS)
175
176AC_PROG_INSTALL
177AC_PROG_RANLIB
178AC_CHECK_PROG([HAVE_ZIP], [zip], [yes], [no])
179if test "x${HAVE_ZIP}" = "xno"; then
180   AC_MSG_ERROR([cannot find a 'zip' binary.])
181fi
182
183AC_CONFIG_LIBOBJ_DIR([compat])
184AC_CHECK_DECLS([memrchr])
185AC_REPLACE_FUNCS([memrchr])
186
187AC_CONFIG_FILES([Makefile compat/Makefile libfaim/Makefile perl/Makefile perl/modules/Makefile])
188AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.