source: configure.ac @ 7d03c8d

release-1.6release-1.7release-1.8release-1.9
Last change on this file since 7d03c8d was 7d03c8d, checked in by Nelson Elhage <nelhage@mit.edu>, 11 years ago
Add zcrypt to our build system.
  • Property mode set to 100644
File size: 4.3 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2AC_INIT([BarnOwl],[1.6dev],[bug-barnowl@mit.edu])
3AM_INIT_AUTOMAKE([1.7.0 -Wall -Wno-portability foreign])
4m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
5
6AC_CONFIG_MACRO_DIR([m4])
7AC_CONFIG_HEADER([config.h])
8
9AC_PROG_CC
10
11AC_ARG_WITH([stack-protector],
12  [AS_HELP_STRING([--with-stack-protector],
13    [Enable gcc -fstack-protector])],
14  [],
15  [with_stack_protector=check])
16
17AS_IF([test "x$with_stack_protector" != xno],
18  [AX_C_CHECK_FLAG([-fstack-protector],[],[],
19    [CFLAGS="$CFLAGS -fstack-protector"],
20    [if test "x$with_stack_protector" != xcheck; then
21       AC_MSG_FAILURE([--with-stack-protector selected, but gcc does support it.])
22     fi
23    ])])
24
25AC_CHECK_LIB(ncursesw, initscr,, AC_MSG_ERROR(No libncursesw found.))
26AC_CHECK_LIB(panelw, update_panels,, AC_MSG_ERROR(No libpanelw found.))
27AC_SEARCH_LIBS([gethostbyname], [nsl])
28AC_SEARCH_LIBS([socket], [socket])
29AC_SEARCH_LIBS([res_search], [resolv])
30
31AC_ARG_WITH([zephyr],
32  [AS_HELP_STRING([--with-zephyr],
33    [Enable Zephyr support])],
34  [],
35  [with_zephyr=check])
36
37AS_IF([test "x$with_zephyr" != xno],
38  [AC_MSG_CHECKING([for Kerberos IV])
39   AS_IF([krb5-config krb4 --libs >/dev/null 2>&1],
40     [AC_MSG_RESULT([yes])
41      AC_DEFINE([HAVE_KERBEROS_IV], [1], [Define if you have kerberos IV])
42      CFLAGS="${CFLAGS} `krb5-config krb4 --cflags`"
43      LIBS="${LIBS} `krb5-config krb4 --libs`"
44     ],
45     [AC_MSG_RESULT([no])
46      PKG_CHECK_MODULES([LIBCRYPTO], [libcrypto])
47      CFLAGS="${CFLAGS} ${LIBCRYPTO_CFLAGS}"
48      LIBS="${LIBS} ${LIBCRYPTO_LIBS}"
49     ])
50   AC_CHECK_LIB([zephyr], [ZGetSender],
51   [LIBS="$LIBS -lzephyr"
52    AC_DEFINE([HAVE_LIBZEPHYR], [1],
53                [Define if you have libzephyr])
54    AC_CHECK_LIB([zephyr], [ZInitLocationInfo],
55      AC_DEFINE([HAVE_LIBZEPHYR_ZINITLOCATIONINFO], [1],
56                [Have ZInitLocationInfo]),)
57    AC_CHECK_LIB([com_err], [com_err])
58    AC_CHECK_HEADERS([com_err.h])
59   ],
60   [if test "x$with_zephyr" != xcheck; then
61      AC_MSG_FAILURE(
62        [--with-zephyr was given, but libzephyr does not seem to be available.])
63    fi
64   ])])
65
66AC_CHECK_FUNCS([use_default_colors resizeterm])
67AC_CHECK_FUNCS([des_string_to_key DES_string_to_key], [HAVE_DES_STRING_TO_KEY=1])
68AC_CHECK_FUNCS([des_ecb_encrypt DES_ecb_encrypt], [HAVE_DES_ECB_ENCRYPT=1])
69AC_CHECK_FUNCS([des_key_sched DES_key_sched], [HAVE_DES_KEY_SCHED=1])
70
71dnl Checks for header files.
72AC_HEADER_STDC
73AC_HEADER_SYS_WAIT
74AC_CHECK_HEADERS(strings.h sys/ioctl.h sys/filio.h unistd.h)
75
76dnl Add CFLAGS for embeded perl
77PERL_CFLAGS=`perl -MExtUtils::Embed -e ccopts`
78AC_MSG_NOTICE([Adding perl CFLAGS ${PERL_CFLAGS}])
79CFLAGS="${CFLAGS} ${PERL_CFLAGS}"
80
81dnl Find the location of perl XSUBPP
82AC_MSG_CHECKING(for the perl xsubpp precompiler)
83XSUBPPDIR="`(perl -MExtUtils::MakeMaker -e 'print ExtUtils::MakeMaker->new({NAME => qw(owl)})->tool_xsubpp;') | grep \^XSUBPPDIR | sed -e 's/XSUBPPDIR = //g;'`"
84if test -n "${XSUBPPDIR}"; then
85   AC_MSG_RESULT(${XSUBPPDIR})
86else
87   AC_MSG_ERROR(not found)
88fi
89
90if test -f "${XSUBPPDIR}/typemap"; then
91   XSUBPPFLAGS="-typemap ${XSUBPPDIR}/typemap"
92else
93   XSUBPPFLAGS=""
94fi
95
96dnl Add LDFLAGS for embedded perl
97FOO=`perl -MExtUtils::Embed -e ldopts`
98AC_MSG_NOTICE([Adding perl LIBS ${FOO}])
99LIBS=${LIBS}\ ${FOO}
100
101dnl Add CFLAGS and LDFLAGS for glib-2.0
102PKG_CHECK_MODULES(GLIB,glib-2.0)
103
104AC_MSG_NOTICE([Adding glib-2.0 CFLAGS ${GLIB_CFLAGS}])
105CFLAGS="${GLIB_CFLAGS} ${CFLAGS}"
106AC_MSG_NOTICE([Adding glib-2.0 LDFLAGS ${GLIB_LIBS}])
107LDFLAGS="${GLIB_LIBS} ${LDFLAGS}"
108
109if test "x${prefix}" = "xNONE"; then
110   prefix="${ac_default_prefix}"
111fi
112
113AC_DEFINE_UNQUOTED([DATADIR],["${prefix}/share/${PACKAGE}"],
114                   [Package data directory])
115
116dnl Checks for typedefs, structures, and compiler characteristics.
117
118AX_CFLAGS_WARN_ALL
119AX_CFLAGS_STRICT_PROTOTYPES
120
121AX_C_CHECK_FLAG([-Wno-pointer-sign],[],[],
122  [LIBFAIM_CFLAGS="$LIBFAIM_CFLAGS -Wno-pointer-sign"])
123
124AM_CONDITIONAL([ENABLE_ZCRYPT], [test "$HAVE_DES_STRING_TO_KEY" && dnl
125                                 test "$HAVE_DES_KEY_SCHED" && dnl
126                                 test "$HAVE_DES_ECB_ENCRYPT"])
127
128AC_SUBST([LIBFAIM_CFLAGS])
129
130AC_SUBST(XSUBPPDIR)
131AC_SUBST(XSUBPPFLAGS)
132
133AC_PROG_INSTALL
134AC_PROG_RANLIB
135
136AC_CONFIG_FILES([Makefile libfaim/Makefile perl/Makefile perl/modules/Makefile])
137AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.